annotated_annals/flake.nix

{
    description = "Annotated Annals: A blog";

    inputs.nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";
    inputs.flake-utils.url = "github:numtide/flake-utils";
    inputs.hermit-zola = { url = "github:IslandUsurper/hermit_zola"; flake = false; };

    outputs = { self, nixpkgs, flake-utils, hermit-zola }:
    flake-utils.lib.eachDefaultSystem (system:
    let
        pkgs = nixpkgs.legacyPackages.${system};
        themeName = "hermit_zola";
    in
    with pkgs;
    {
        packages.blog = stdenv.mkDerivation rec {
            pname = "annotated-annals";
            version = "2025-06-25";
            src = ./.;
            nativeBuildInputs = [ zola ];
            configurePhase = ''
              if [ -h "themes/${themeName}" ]; then
                rm "themes/${themeName}"
              fi
              mkdir -p "themes/${themeName}"
              cp -a ${hermit-zola}/* "themes/${themeName}/"
            '';
            buildPhase = "${zola}/bin/zola build";
            installPhase = "cp -r public $out";
        };

        defaultPackage = self.packages.${system}.blog;

        devShell = mkShell {
            packages = [ just zola ];
            shellHook = ''
                ln -fsn "${hermit-zola}" "themes/${themeName}"
            '';
        };
    });
}